Түйін

Лицензиялау

Мен бұл туындының авторымын, келесі лицензия аясында бұны жариялаймын:

Бұл файлды GNU Free Documentation License лицензиясының 1.2 нұсқасы бойынша немесе ескі Ашық бағдарламалық жасақтаушы қорымен жарияланған нұсқасының шарттарына сәйкес көшірмесін алуға, таратуға және/немесе өзгертуге болады. Лицензия көшірмесі GNU Free Documentation License деп аталынған бөлімде көрсетілген.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

	Бұл файл Creative Commons Attribution-Share Alike 3.0 Unported лицензиясы бойынша қолжетімді.
	Сіз келесі әрекеттерге еркінсіз: бөлісу – туындыны көшіру, тарату және тапсыру мазмұнын өзгерту – туындыны бейімдеу Келесі ережелерді сақтағанда: атрибуция – Авторлықты белгілеп, лицензияға сілтеме беріп, өзгеріс жасалғанын анықтауыңыз керек. Сіз мұны кез келген орынды жолмен істей аласыз, бірақ лицензиар сізді немесе қолдануыңызды мақұлдайтындай емес. бірдей шарттарда тарату – Материалды араластырсаңыз, түрлендірсеңіз немесе құрастырсаңыз, үлестеріңізді түпнұсқамен бірдей бірдей немесе үйлесімді лицензия бойынша таратуыңыз керек.
	Лицензияландырудың бұл қасиеті осы файлға GFDL лицензиясының жаңартылуының бір бөлігі ретінде енгізілген.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue

Бұл файл Creative Commons Attribution-Share Alike 2.5 Spain лицензиясы бойынша қолжетімді.

Сіз келесі әрекеттерге еркінсіз:

• бөлісу – туындыны көшіру, тарату және тапсыру
• мазмұнын өзгерту – туындыны бейімдеу

Келесі ережелерді сақтағанда:

• атрибуция – Авторлықты белгілеп, лицензияға сілтеме беріп, өзгеріс жасалғанын анықтауыңыз керек. Сіз мұны кез келген орынды жолмен істей аласыз, бірақ лицензиар сізді немесе қолдануыңызды мақұлдайтындай емес.
• бірдей шарттарда тарату – Материалды араластырсаңыз, түрлендірсеңіз немесе құрастырсаңыз, үлестеріңізді түпнұсқамен бірдей бірдей немесе үйлесімді лицензия бойынша таратуыңыз керек.

https://creativecommons.org/licenses/by-sa/2.5/es/deed.enCC BY-SA 2.5 esCreative Commons Attribution-Share Alike 2.5 estruetrue

Өз қалауыңызбен лицензияны таңдауыңызға болады.

POV-Ray Scene description

POV-ray image description:

/*
--------------------------
Parabolic Orbit Animation
--------------------------
Created 7 Mar. 2006
*/
#include "colors.inc"

//Orbit Definition
#declare OrbitRp=6.356*1.8;

//Scene Constants
#declare EarthRadius=6.356;
#declare SatRadius=1.2;
#declare OrbitWidth=0.5;
#declare LineWidth=0.5/3;
#declare Crosslength=1.5;
#declare Textscale=9;
#declare TextColor=rgb<0,0,0>;
#declare xinit=-100;

//Variables
#declare Minit=2*OrbitRp*sqrt(2*OrbitRp-xinit)+pow(sqrt(2*OrbitRp-xinit),3)/3;
#declare M=Minit-2*clock*Minit;
#declare PI=3.14159265359;

//Anomaly Determination - Solves the equation M=2*OrbitRp*D+D^3/3
#declare p=6*OrbitRp;
#declare q=-3*M;
#declare A1=q/2+sqrt(pow(q,2)/4+pow(p,3)/27);
#if (A1>0)
    #declare U=pow(A1,1/3);
#else
    #declare U=-pow(-A1,1/3);
#end
#declare Anomaly=p/(3*U)-U;

//General settings
global_settings{
    ambient_light 1
}

light_source { <-50, 0, -70> color White }

camera {
  orthographic
  location <0, 0, -10>
  look_at  <0, 0,  0>
  up <0,100,0>
  right <100,0,0>
}

plane { <0, 0, 1>, 8
    pigment {White}
    finish{ambient 1 brilliance 0}
}


//Earth
sphere {
    <0, 0, 0>, EarthRadius
    pigment { Blue }
    finish{ ambient 0.3 brilliance 1.2 diffuse 0.8}
}


//Orbit
intersection{
    box{
        <-100,-100,-OrbitWidth>, <100,100,OrbitWidth> 
    }
    quadric{
        <0,1/(4*OrbitRp),0>,<0,0,0>,<-1,0,0>,-OrbitRp
        translate -x*OrbitWidth/2
    }
    quadric{
        <0,-1/(4*OrbitRp),0>,<0,0,0>,<1,0,0>,OrbitRp
        translate x*OrbitWidth/2
    }
    pigment{ rgb<0.8,0,0> }
    finish{ ambient 1 brilliance 0 diffuse 0}
    rotate 2.2*y
    no_shadow
}


//Satellite
sphere {
    <0, 0, -10>, SatRadius
    pigment { SeaGreen }
    finish{ ambient 1 brilliance 0 diffuse 0}
    no_shadow
    translate <-(OrbitRp-Anomaly*Anomaly/2),sqrt(2*OrbitRp)*Anomaly,0>
}

//Lines
#declare crossBars=
object{
    union{
        box{
            <-LineWidth,-Crosslength,-LineWidth-7>, <LineWidth,Crosslength,LineWidth-7> 
        }
        box{
            <-Crosslength,-LineWidth,-LineWidth-7>, <Crosslength,LineWidth,LineWidth-7>
        }
        rotate z*45
        pigment{ TextColor }
        finish{ ambient 1 brilliance 0 diffuse 0}
        no_shadow
    }
}

box{
    <-OrbitRp,-LineWidth,-LineWidth-7>, <0,LineWidth,LineWidth-7> 
    pigment{ TextColor }
    finish{ ambient 1 brilliance 0 diffuse 0}
    no_shadow
}


object{
    crossBars
}

object{
    crossBars
    translate -x*OrbitRp
}


//Text
union{
    text {
        ttf "timesi.ttf" "r" 1, 0
    }
    text {
        ttf "timesi.ttf" "p" 1, 0
        scale 0.5
        translate 0.2*x
    }
    pigment{ TextColor }
    finish{ ambient 1 brilliance 0 diffuse 0}
    scale Textscale
    translate <-(EarthRadius+0.3*(OrbitRp-EarthRadius))-Textscale/4,Textscale/4,-7>
    no_shadow
}